home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / identity.pro < prev    next >
Text File  |  1997-07-08  |  2KB  |  65 lines
  1. ; $Id: identity.pro,v 1.5 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1996-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5. ;+
  6. ; NAME:
  7. ;       IDENTITY
  8. ;
  9. ; PURPOSE:
  10. ;       This function returns an N by N identity array, an array with
  11. ;       ones along the main diagonal and zeros elsewhere.
  12. ;
  13. ; CATEGORY:
  14. ;       Linear Algebra.
  15. ;
  16. ; CALLING SEQUENCE:
  17. ;       Result = IDENTITY(N)
  18. ;
  19. ; INPUTS:
  20. ;       N:      The desired column and row dimensions.
  21. ;
  22. ; KEYWORD PARAMETERS:
  23. ;       DOUBLE: If set to a non-zero value, a double precision identity array
  24. ;               is returned.
  25. ;
  26. ; EXAMPLE:
  27. ;       Define an array, A.
  28. ;         A = [[ 2.0,  1.0,  1.0, 1.5], $
  29. ;              [ 4.0, -6.0,  0.0, 0.0], $
  30. ;              [-2.0,  7.0,  2.0, 2.5], $
  31. ;              [ 1.0,  0.5,  0.0, 5.0]]
  32. ; 
  33. ;       Compute the inverse of A using the INVERT function.
  34. ;         Inverse = INVERT(A)
  35. ;
  36. ;       Verify the accuracy of the computed inverse using the mathematical
  37. ;       identity, A x A^-1 - I(4) = 0; where A^-1 is the inverse of A, I(4)
  38. ;       is the 4 by 4 identity array and 0 is a 4 by 4 array of zeros.
  39. ;         PRINT, A ## Inverse - IDENTITY(4)
  40. ;
  41. ; REFERENCE:
  42. ;       ADVANCED ENGINEERING MATHEMATICS (seventh edition)
  43. ;       Erwin Kreyszig
  44. ;       ISBN 0-471-55380-8
  45. ;
  46. ; MODIFICATION HISTORY:
  47. ;       Written by:  GGS, RSI, January 1996
  48. ;-
  49.  
  50. FUNCTION Identity, N, Double = Double
  51.  
  52.   ON_ERROR, 2
  53.   if N le 0 then MESSAGE, "N parameter must be greater than 0."
  54.  
  55.   if KEYWORD_SET(Double) eq 0 then begin
  56.     Array = FLTARR(N, N) 
  57.     Array[LINDGEN(N) * (N+1)] = 1.0
  58.   endif else begin
  59.     Array = DBLARR(N, N)
  60.     Array[LINDGEN(N) * (N+1)] = 1.0d
  61.   endelse
  62.  
  63.   RETURN, Array
  64. end
  65.